TM1637 display with ESP8266 or ESP32: an NTP clock in 18 lines of code

Step 1

What do you need for this?

Arduino IDE (free) — with the ESP8266 and ESP32 board manager URLs configured
TM1637 display — for example via Amazon
WiFiManager library — for a WiFi connection without a hard-coded password
TM1637Display library — driving the display
An ESP8266 or ESP32 board — e.g. an inexpensive starter pack
Solderless connecting wires

ESP8266

TM1637 display + ESP8266

Connections:

ESP8266 -> TM1637
=================
GND --------> GND
3V3 --------> VCC
D2  --------> DIO
D1  --------> CLK

Sketch for a simple clock:

#include <WiFiManager.h>    // https://github.com/tzapu/WiFiManager/
#include <TM1637Display.h>  // https://github.com/avishorp/TM1637/

struct tm tInfo;  // https://cplusplus.com/reference/ctime/tm/
WiFiManager myWiFi;
TM1637Display ledSeg(5, 4);  // scl (clk) -> GPIO5 (D1) / sda (dio) -> GPIO4 (D2).

void setup() {
  Serial.begin(115200);                                           // watch serial monitor in case of new WiFi-connection
  myWiFi.autoConnect("TM1637_ESP");                               // connect ESP to new wifi via GSM or PC in that case
  ledSeg.setBrightness(2);                                        // 0 .. 7
  configTzTime("CET-1CEST,M3.5.0,M10.5.0/3", "be.pool.ntp.org");  // https://github.com/nayarsystems/posix_tz_db/blob/master/zones.csv
}

void loop() {
  getLocalTime(&tInfo);                                                                           // sntp sync at startup & every hour from then on
  ledSeg.showNumberDecEx(tInfo.tm_hour * 100 + tInfo.tm_min, 0x40 * (millis() % 1000 < 500), 1);  // 0x40 = ":", 1 = leading zeros
}

adjusts for daylight saving time automatically
synchronizes once an hour with SNTP server
can connect to any WiFi without changing the code (adjustable with e.g. tablet or smartphone)
no "hard coded" password
only 18 lines of code
no delay() commands

How does it work?

#include <WiFiManager.h> — library to connect the ESP to the WiFi, including a web server if the WiFi data was not previously entered. If the connection fails, you will see on the serial monitor:
- *wm:StartAP with SSID: TM1637_ESP
- *wm:AP IP address: 192.168.4.1
- *wm:Starting Web Portal
You need to connect to this access point with your cell phone or tablet or PC, launch a browser and enter 192.168.4.1 as the address, and you can enter the WiFi data. The advantage is that you can move the ESP elsewhere (or change a WiFi access point) without recompiling the code. Even without a serial monitor, you will notice if the clock does not work: then you also have to connect via the access point and enter the WiFi data. Once the clock has started you can disconnect the WiFi connection, the clock will just keep running (obviously without synchronization in that case).
The last lines in the functions "setup" and "loop" are powerful, they execute a lot on 1 line:
- configTzTime("CET-1CEST,M3.5.0,M10.5.0/3", "be.pool.ntp.org"); — this is the line that ensures that the correct time zone is used, the clock automatically adjusts to summer or winter time, and then indicates which NTP servers you wish to synchronize with.
- ledSeg.showNumberDecEx(ti.tm_hour * 100 + ti.tm_min, 0x40 * (millis() % 1000 < 500), 1); — the time is shown on the display with a colon (hidden or shown every half second), and with leading zeros.
getLocalTime(&timeinfo); requests the time from the ESP8266, adjusted according to time zone and daylight saving time / standard time. On startup the internal clock is synchronized with the NTP server, thereafter the synchronization occurs every hour. This was extensively tested with callback functions.
There is no interval set for synchronization with SNTP. By default (ESP8266) that interval is set to 1 hour, which is more than enough to get the correct time. Update to standard time / DST is also done without synchronization. The update via NTP always happens in UTC time, never in local time — and it is local time that controls daylight saving time or standard time.

Where are the libraries? In the many examples of clocks you find on the Internet, you see "NTPClient.h", "Time.h", "TimeLib.h" and "WiFiUDP.h". Where are those in this sketch? Short answer: you don't need those. Time.h is built into the ESP core. So we should not add these libraries to the list of the Arduino IDE, and we should not declare them in these sketches.

ESP32

TM1637 display + ESP32

The following code for our "minimum clock" is adapted for both the ESP8266 and the ESP32. The default time synchronization interval for the ESP32 is 3 hours, for the ESP8266 it is 1 hour. The only modifications are the display GPIO connections:

Connections:

ESP32 ---> TM1637
=================
GND --------> GND
3V3 --------> VCC
G21 --------> DIO
G22 --------> CLK

Sketch:

#include <WiFiManager.h>    // https://github.com/tzapu/WiFiManager/
#include <TM1637Display.h>  // https://github.com/avishorp/TM1637/

struct tm tInfo;  // https://cplusplus.com/reference/ctime/tm/
WiFiManager myWiFi;
#if defined(ESP32)  
TM1637Display ledSeg(22, 21);  // scl (clk) -> G22 / sda (dio) -> G21.
#elif defined(ESP8266)
TM1637Display ledSeg(5, 4);  // scl (clk) -> GPIO5 (D1) / sda (dio) -> GPIO4 (D2).
#endif

void setup() {
  Serial.begin(115200);                                           // watch serial monitor in case of new WiFi-connection
  myWiFi.autoConnect("TM1637_ESP");                               // connect ESP to new wifi via GSM or PC in that case
  ledSeg.setBrightness(2);                                        // 0 .. 7
  configTzTime("CET-1CEST,M3.5.0,M10.5.0/3", "be.pool.ntp.org");  // https://github.com/nayarsystems/posix_tz_db/blob/master/zones.csv
}

void loop() {
  getLocalTime(&tInfo);                                                                           // sntp sync at startup & every hour from then on
  ledSeg.showNumberDecEx(tInfo.tm_hour * 100 + tInfo.tm_min, 0x40 * (millis() % 1000 < 500), 1);  // 0x40 = ":", 1 = leading zeros
}

We could extend the sketch so that when the clock establishes a WiFi connection during startup, it looks up its own location via an API. Then the time zone could be assigned automatically. Thus, you could create an NTP clock with the ESP that you could use anywhere in the world. After connecting to an available WiFi, it displays the correct local time.

More displays with the ESP8266 / ESP32

Curious about other displays? Check out the full overview, including SSD1306, SH1106, ST7735, ST7789, e-paper and integrated displays like the Lilygo T-Display and the Waveshare ESP32-S3.